loading
首先，想說一下我寫此文的動機(jī)，
完美的loading—完美到底
。記得很早之前我曾經(jīng)說過“沒有l(wèi)oading的flash，不是完整的flash”。我想那個句話可能偏激了。因?yàn)橛袝r候一些不到10k的flash，確實(shí)不需要做什么loading。但我始終認(rèn)為，做一個優(yōu)秀的loading是衡量一個flasher水準(zhǔn)，甚至態(tài)度的。你問我為什么，我可以告訴你，因?yàn)閘oading是唯一一個你不會多看而所有用戶、客戶會看的東西，所以你對loading的重視程度，甚至可以反襯你這個flasher的職業(yè)道德！有些做設(shè)計為主的朋友，我認(rèn)識不少，他們對loading都是得過且過的態(tài)度，做一個loading，更多的是自己找一個現(xiàn)成的，然后每次去套用，我個人認(rèn)為是很不好的習(xí)慣。并不是說我不提倡代碼、元件的重用度，而是我覺得對于loading這種東西，套多了，是要出問題的。我強(qiáng)烈建議那些已經(jīng)達(dá)到可以修改人家loading水平的flasher看看我的東西，當(dāng)然，如果你連flash的as該寫在哪都不知道，建議先入門了。
好，下面切入正題，如何制作loading：
首先要感激Macromedia的大智慧，提供了很好的兩個函數(shù)使我們可以做出完美的loading，那就是getBytesLoaded和getBytesTotal。請不要再用你改來改去改了兩三年的那個什么getFrameLoaded什么什么了，我都記不清楚怎么拼了。我只想說，F(xiàn)rame的觀念將在真正的Interactive-Design中淡化。更別提什么Scene，那是Flash的敗筆！
那么loading如何工作呢？我們?nèi)绾卫眠@兩個函數(shù)呢？這里要提到一個重要的概念。就是間隔調(diào)用。間隔調(diào)用有多種方式，下面列舉出來，并列舉出其在loading制作中的地位和用法，歡迎補(bǔ)充：
·setInterval方式
寫法：
function loadCheck()
{
var p = getBytesLoaded()/getBytesTotal();
if (p==1)
{
clearInterval(intervalID); // 釋放間隔調(diào)用
gotoAndPlay(someFrame); // 開始播放
}
}
var interval = 30; // 這個數(shù)值是刷新頻率
var intervalID = setInterval(loadCheck,interval);
我個人并不推薦初學(xué)者用這種寫法。因?yàn)楹芏嗳巳菀缀鲆昪learInterval，而這個東西被忽視掉，是很恐怖的！如果你的setInterval沒有給及時移除，意味著你將在整個swf的播放過程中增加一個沒有必要的負(fù)擔(dān)！
而且這種方法很不適合控制MoiveClip的狀況（因?yàn)槌鯇W(xué)者會發(fā)現(xiàn)MC的路徑是個大問題，而loadCheck本身就是個函數(shù)，還是被setInterval調(diào)用的，要在loadCheck中指一個路徑出來，挺麻煩的，你不要指望_root，那樣會讓你的程序不規(guī)范；也不要指望this，因?yàn)樵诤瘮?shù)中用this似乎不太理想；最好什么都不寫，但往往你不敢不寫），進(jìn)而做出更好的效果。
·onEnterFrame方式
我最喜歡的就是這種方法了。比較方便、直觀。因?yàn)橥覀兪且靡粋�MC體現(xiàn)一個loading的進(jìn)度，比如，一個進(jìn)度條，或者更有創(chuàng)意的東西，只有你不能想到的，沒有你不能做到的。
那么究竟如何用呢。首先，把創(chuàng)意定好。然后給你的MC一個實(shí)例名字，比如叫做loader_mc。這時候在timeline上寫代碼，記住，是timeline而不是MC上。因?yàn)檫@樣便于代碼統(tǒng)一、便于路徑統(tǒng)一、便于管理和尋找。別為了省幾個字母就把代碼通通搬到button，mc上面去，然后一個on(press)了事。除非你是在敷衍你的作品；或者你是在為了交作業(yè)。
loader_mc.onEnterFrame. = function ()
{
var getTar:MovieClip = this._parent;
var p = getTar.getBytesLoaded()/getTar.getBytesTotal();
trace(p);
if(p==1)
{
this.onEnterFrame. = null;
gotoAndPlay(someFrame); // 開始播放
}
}
就這么簡單，記住，在MC的事件函數(shù)體內(nèi)部引用MC，永遠(yuǎn)是一件很快的事情。因?yàn)閠his就可以指向這個MC本身，通過諸如this._parent之類的方法，可以找到你所有的MC!
·直接依賴于timeline的循環(huán)方式
非常非常非常古老的方式了，不介紹了。不過你們可以去問問那些一直不喜歡自己動手做loading的flasher，他們也許在改的某一個版本就是這個，呵呵。
以上算是比較簡單的。比較容易出問題的，還有兩個。
第一、MovieClipLoader
第二、含有多種V2組件的Loader
讀取外埠數(shù)據(jù)參與Flash應(yīng)用程序部署是一件非常重要和常見的工作，尤其是我們常常需要檢測這些數(shù)據(jù)加載的進(jìn)度。而MovieClipLoader(下稱MCL)類卻幫我們大大簡化了這項(xiàng)麻煩工作。此外，它使得我們能獲取更多的需要，并減少代碼量。我們可以用一個單獨(dú)的MovieClip類來載入一個，或者多個外埠資源到指定的MC或者層級，或者我們可以為每一個加載工作制定不同的MCL實(shí)例。
我決定分兩部分來完成這篇教程。首先，我們將介紹MCL的基本用法；然后我們將介紹如何使用一個單獨(dú)的MCL實(shí)例來讀取外埠資源到不同的MC，并且，我們將加入偵聽器對象來參與工作。當(dāng)然，不通過偵聽器也可以完成任務(wù)，我們暫時不介紹偵聽器，因?yàn)檫@樣你會更加容易理解MCL。
那么，我們首先來大體了解一下MCL有哪些回調(diào)函數(shù)，后面也會有詳細(xì)介紹（aw附:回調(diào)函數(shù)我個人理解就是某一個類組、參數(shù)事先確定，擁有指定功效的方法）這里可以了解一下什么叫做回調(diào)函數(shù)）：
MovieClipLoader對象的回調(diào)函數(shù):
事件回調(diào)函數(shù)（嚴(yán)格要求數(shù)據(jù)類型的時候，它們并不是方法，后祥）：
* MovieClipLoader.onLoadStart() - 當(dāng)加載開始的時候觸發(fā)
* MovieClipLoader.onLoadProgress() - 在讀取進(jìn)行中觸發(fā)
* MovieClipLoader.onLoadInit() - 讀取資源載入后的第一幀執(zhí)行完成后觸發(fā)
* MovieClipLoader.onLoadComplete() - 當(dāng)讀取的外埠資源已經(jīng)完全下載到本地時觸發(fā)。
* MovieClipLoader.onLoadError() - 當(dāng)加載外埠資源出錯時觸發(fā)。
* MovieClipLoader.unloadClip() - 將加載的外埠資源移除或終止一個加載工作。
方法回調(diào)函數(shù)：
* MovieClipLoader.getProgress(target:Object):Object - 讀取外埠資源的進(jìn)展，參數(shù)為MC對象(aw附：其實(shí)MC這種數(shù)據(jù)類型也就是一種對象)。返回一個對象，該對象包含兩種事先預(yù)定好的屬性(后祥)
要想好好理解這些回調(diào)函數(shù)，我們動手試驗(yàn)一下是最好的方法。當(dāng)然MCL是Flash7之后才有的，所以別忘了發(fā)布的時候發(fā)布成為7+的版本號。如果直接用FlashPlayer來調(diào)試可能會遇到一些問題，我們推薦在瀏覽器中進(jìn)行調(diào)試（個人意見：對于外埠資源難以獲得情況，比如教育網(wǎng)獲取公網(wǎng)資源，最好不要在IDE中調(diào)試）
在我們的例子中，我們將用一個MCL對象來讀取不同的圖片，并將它們置入不同的空MC中。本例中要用到的swf文件和圖像源文件將在Actionscript.org找到（個人建議：其實(shí)看完這篇文章要不要源文件沒有必要了）
1、建立一個新的Flash文檔，并在第1幀輸入以下腳本：
_root.traceBox.vScrollPolicy ="on";
function myTrace(msg)
{
_root.traceBox.text += msg + newline;
_root.traceBox.vPosition = _root.traceBox.maxVPosition;
}
我們這里是在建立一種跟蹤調(diào)試機(jī)制，調(diào)試的(變量)將輸出到文本框組件中。這里的方法"myTrace"是預(yù)先定義好的一個函數(shù),它幫助我們順利完成對某些信息的監(jiān)控；其中第二句的作用是使文本框隨時輸出最新監(jiān)控值。
2、現(xiàn)在從組建庫托拽一個TextArea組件進(jìn)入場景，并給以合適的大小，以及一個實(shí)例名稱traceBox(對應(yīng)上面的腳本)
3、接下來，我們要建立一個新的MC元件。并在場景上部署3個實(shí)例，為它們分別命名為myMC1,myMC2,myMC3。我們將把圖片或者swf影片裝載進(jìn)入它們，并且，在它們下載到本地后按照需求調(diào)整它們的尺寸。其實(shí)，對圖片人為地改變尺寸會造成許多不好的后果，比如鋸齒的產(chǎn)生，但是為了讓大家了解onLoadInit事件的使用，我們將會這么做。
4、然后，我們建立一個MCL對象，在第一幀輸入以下腳本：
var myMCL = new MovieClipLoader();//create an instance of MovieClipLoader
aw附：這里我想羅索以下，關(guān)于Object的翻譯。因?yàn)樯鲜龃a的注釋中，老外用的是instance這個詞，直譯的話，Object是“對象”；Instance代表“實(shí)例”。前者更注重于其數(shù)據(jù)類型，而后者則更注重于其客觀存在性。
5. 現(xiàn)在我們就可以部署腳本了，在第一幀：
myMCL.onLoadStart = function (targetMC)
{
var loadProgress = myMCL.getProgress(targetMC);
myTrace ("The movieclip " + targetMC + " has started loading");
myTrace("Bytes loaded at start=" + loadProgress.bytesLoaded);
myTrace("Total bytes loaded at start=" + loadProgress.bytesTotal);
}
這個函數(shù)的第一行中申明了一個(對象類型的)變量，顯然，這個變量的值由myMCL對象的getProgress方法獲得.剛才已經(jīng)介紹了getProgress方法,這里可以看到,返回的loadProgress.bytesLoaded就是loadProgress對象的bytesLoaded屬性.
這里我再啰嗦一句：為什么返回一個對象，而不返回具體的值。這是有原因的。函數(shù)返回值的功能使得程序設(shè)計更加完美，然而很多情況下，我們要返回的并非一個值，我們可能返回兩個或者更多的值，甚至它們的數(shù)據(jù)類型都不相同。這樣，只有通過對象的形式來返回了。這是解決問題最簡單最高效的方法。下面三句myTrace就呼應(yīng)了之前我們定義的監(jiān)控函數(shù)，這樣就能看到我們關(guān)注的變量了。
6、我們已經(jīng)為onLoadStart事件部署了相應(yīng)的工作，接下來我們要為上述其他事件部署工作了。緊接著是onLoadProgress，它接受三個參數(shù)：targetMC, loadedBytes, totalBytes。分別代表目標(biāo)容器MC實(shí)例；已經(jīng)讀取的體積、總體積。
myMCL.onLoadProgress = function (targetMC, loadedBytes, totalBytes) {
myTrace ("movie clip: " + targetMC);
myTrace("Bytes loaded at progress callback=" + loadedBytes);
myTrace("Bytes total at progress callback=" + totalBytes);
}
7、我們的onLoadComplete方法僅接受一個參數(shù)，它就是容器MC實(shí)例。像onLoadStart一樣，我們用getProgress方法來返回讀取情況。
myMCL.onLoadComplete = function (targetMC)
{
var loadProgress = myMCL.getProgress(targetMC);
myTrace (targetMC + " has finished loading.");
myTrace("Bytes loaded at end=" + loadProgress.bytesLoaded);
myTrace("Bytes total at end=" + loadProgress.bytesTotal);
}
8、onLoadInit方法將在所有加載的內(nèi)容被下載到本地容器MC中之后才開始執(zhí)行。這將使得你能更好的控制加載進(jìn)來的內(nèi)容的屬性。我選擇的圖片非常大，這樣我們可以把讀取過程看得更加清晰，而我也要對已經(jīng)加載的圖片尺寸進(jìn)行修整，讓它能全部顯示出來。
myMCL.onLoadInit = function (targetMC)
{
myTrace ("Movie clip:" + targetMC + " is now initialized");
targetMC._width = 170;
targetMC._height = 170;
}
9、還有一個回調(diào)方法onLoadError。如果有錯誤發(fā)生，它將會被觸發(fā)。作為一個優(yōu)秀的程序員，部署完善的應(yīng)用程序的時候，對錯誤發(fā)生的避免措施是必不可少的！
myMCL.onLoadError = function (targetMC, errorCode)
{
myTrace ("ERRORCODE:" + errorCode);
myTrace (targetMC + "Failed to load its content");
}
10. Well that's the hard work out of the way. Now we just have to load the files in to their respective targets, using loadClip, and passing it two arguments: the location of your file, and the destination movieclip for the file to load in to.
10、我們終于將最復(fù)雜的工作部署好了，
電腦資料
《完美的loading—完美到底》(http://www.ishadingyu.com)。接下來我們只用使用loadClip方法讀入我們需要的內(nèi)容就行了。loadClip方法的兩個參數(shù)分別是外埠資源的地址和容器MC的實(shí)例。
myMCL.loadClip("http://www.yourdomain.com/test1.swf","_root.myMC1");
myMCL.loadClip("http://www.yourdomain.com/test2.swf ", "_root.myMC2");
myMCL.loadClip("http://www.yourdomain.com/pic.jpg", "_level0.myMC3");
路徑可以選擇相對路徑。注意，路徑的相對性也是一個大問題，當(dāng)SWF在非本路徑的HTML中被引用的時候，遵從HTML所在的路徑！這一點(diǎn)是很多Flash教程都忽視的。所以，有時候絕對路徑也有絕對路徑的好處。[路徑問題源文件下載，下載了就一目了然了
所有的調(diào)試工作最好在瀏覽器中，而非IDE中完成。而且腳本輸出方式必須是AS2。
Remember, for everything to work properly you need to be testing throuhg a browser (and preferably on line so you can see the files loading in real time). You also need to be exporting your code as ActionScript. 2.
In the second part of this tutorial I'm going to show you how to use the MovieClipLoader class in a real-world situation, in order to solve a common problem when assigning event handlers to MovieClips dynamically.
接下來，我將介紹實(shí)時調(diào)用MCL的情況。為了能適應(yīng)更多的應(yīng)用，我們經(jīng)常動態(tài)地為MCL制定工作。
aw話外音：有時候，我們?nèi)绱藢懀?/p>
1、var mcl:MovieClipLoader = new MovieClipLoader ();
2、var mcl = new MovieClipLoader ();
發(fā)現(xiàn)第一種寫法無法為MCL制定onLoadStart等事件方法。這是編譯器根據(jù)指定變量的數(shù)據(jù)類型產(chǎn)生的問題。osflash的一些朋友給了一些有用的觀點(diǎn)，我也發(fā)現(xiàn)這個問題正好涉及到Flash內(nèi)部的事件響應(yīng)機(jī)制，不妨介紹一下：
Flash的三種事件響應(yīng)機(jī)制
1、簡單的回調(diào)函數(shù)，最老的；
2、偵聽器，ASBroadcaster，F(xiàn)lashMX時代；
3、事件偵聽器，EventDispather，F(xiàn)lashMX2004時代
這里，MCL用的是第二種機(jī)制，而整套V2組件則使用最后一套機(jī)制。
附：MCL官方申明，注意：上述方法中，僅包含getProgress方法！
intrinsic class MovieClipLoader
{
function MovieClipLoader();
function addListener(listener:Object):Boolean;
function getProgress(target:Object):Object;
function loadClip(url:String, target:Object):Boolean;
function removeListener(listener:Object):Boolean;
function unloadClip(target:Object):Boolean;
}
個人補(bǔ)充認(rèn)為：1、2在不嚴(yán)格要求數(shù)據(jù)類型的時候可以通用。
下面開始介紹用偵聽器來檢測MCL事件的方法。在此之前，我們解決一個最常見的問題，我們經(jīng)常會在論壇中看到有人這樣提問：
引用 ：
大家好，我動態(tài)地建立了一些MC，并逐個分配給它們一個事件句柄（標(biāo)志）。然后，我將外埠資源讀取到它們之中。但是這些分配好的事件句柄都不工作了！
緊接著，發(fā)問人一般會貼出一對亂七八糟的代碼，并大呼救命。
那么，我們首先來分析一下這個錯誤發(fā)生的原因：當(dāng)外埠資源被載入到一個MC中時，這個MC將會重新初始化。這意味著任何被預(yù)先制定好的代碼都將付之東流。對于開發(fā)人員已經(jīng)手動在舞臺上安排好的MC則并沒有相關(guān)的麻煩，這是因?yàn)槿魏沃苯油ㄟ^onClipEvent制定到MC的代碼都能幸免被重新初始化。而動態(tài)建立的MC則進(jìn)行上述的“初始化”，因?yàn)槲覀兪窃谶\(yùn)行中給它們配置的事件代碼。
我們?nèi)绾伪苊膺@個問題呢？其實(shí)方法太多了，很多論壇也進(jìn)行了極為詳細(xì)的討論，我就不多贅述了。
你現(xiàn)在也許還記得剛才我介紹的“讀取外埠數(shù)據(jù)參與Flash應(yīng)用程序部署是一件非常重要和常見的工作，尤其是我們常常需要檢測這些數(shù)據(jù)加載的進(jìn)度”
我們已經(jīng)介紹了MCL的幾個回調(diào)函數(shù)，所以這里也不再贅述了。我們現(xiàn)在制作這樣一個效果：縮略圖標(biāo)式的圖片瀏覽系統(tǒng)。我們將要從外部讀取一些JPG圖片，將它們放入我們動態(tài)部署的MC中。并且我們希望這些動態(tài)建立的MC都具有各自的onPress事件。我們通過在MC裝載好外部資源之后再為之分配事件。
在我們開始之前，我還想提醒大家注意一些經(jīng)常出現(xiàn)的疏漏：一定要在發(fā)布的時候設(shè)置成Flash7+AS2以上的版本；其次，用瀏覽器測試你的效果，而不是IDE；否則你將會得到奇怪的結(jié)果。
現(xiàn)在，我們開始編制代碼，你會發(fā)現(xiàn)它比你想象的要簡單得多。
1、新建一個Flash文檔。
2、找四張100*100像素的縮略圖片。
3、建立一個動態(tài)文本框，大概在300*300像素左右，使用12號字體，并使之現(xiàn)實(shí)邊框，這樣我們更好監(jiān)測。別忘了設(shè)置它為多行的。
4、建立一個100X100像素的矩形，轉(zhuǎn)變?yōu)镸C，然后將它移出場景。這時候，他已經(jīng)出現(xiàn)在庫中了。在庫中，設(shè)置他的鏈接名為“img”，并使其“在第一幀導(dǎo)出”。其實(shí)這個矩形會在外部資源載入的時候被取代，現(xiàn)在只是為了調(diào)試方便。
5、在剛才放置textBox文本框的層之上新建一層，這一層用于放置我們的代碼，先寫上：
stop();
6、現(xiàn)在我們定義一個MCL的實(shí)例，此外定義一個基本對象，作為我們的偵聽器：
myMCL = new MovieClipLoader(); //define MovieClipLoader
myListener = new Object(); //define listener
7、接下來我們用偵聽器來偵聽onLoadComplete事件，該事件的作用上文已經(jīng)提到了。我們現(xiàn)在把它交給listener對象，而不是MCL實(shí)例。當(dāng)然，最終要把偵聽器對象再交回MCL（以偵聽其回調(diào)函數(shù)）的時候，得到的效果就是我們需要的效果了。
記住，只有當(dāng)讀取完畢的時候，對MC部署事件任務(wù)才是安全可靠的！所以，在onLoadComplete被觸發(fā)的時候才部署這個onPress事件給MC:
myListener.onLoadComplete = function(targetMC){
debug.text += "LOADING OF " + targetMC
+ " COMPLETE" + newline;
targetMC.onPress = function() {
debug.text += newline
+ "targetMC = " + targetMC._name;
}
}
注：上述代碼中有幾行被人為打斷，但這并不影響效果。
你也許已經(jīng)注意到了，MC的實(shí)例名稱在onLoadComplete被觸發(fā)的時候是作為一個參數(shù)的身份傳遞給onLoadComplete的，這樣我們控制這個MC就非常方便了。比如這里就可以用點(diǎn)擊MC來檢測事件是否被成功部署給MC。
8、現(xiàn)在我們建立一個函數(shù)，它包含一個簡單的循環(huán)來部署場景上的MC。并且及時地為每一個部署好的MC分配讀取外埠資源的任務(wù)（loadClip方法），代碼如下：
function initClips(){
for (i=1; i<=4; i++){
this.attachMovie("img", "img" + i, i);
this["img"+i]._x = i*110;
myMCL.loadClip("0" + i + ".jpg" ,
this["img"+i]); //code wrapped
}
}
9、到這里基本上就完成了�，F(xiàn)在我們剩下的工作就是注冊偵聽器并且按照需求調(diào)用相關(guān)函數(shù)、方法，反映到代碼上就是以下兩行：
myMCL.addListener(myListener);
initClips();
注意這里的順序，我們的偵聽器對象在調(diào)用initClip()函數(shù)之前就被作用于MCL實(shí)例了�，F(xiàn)在我們的MC的onPress事件可以順利工作了，因?yàn)楫?dāng)圖片被完全讀入之后，事件才被分配過去。我們的代碼也非常簡潔。我們再也不用為了loading而去制作麻煩的循環(huán)了，MovieClipLoader幫我們完成了所有工作！
附：完整代碼如下：
stop();
myMCL = new MovieClipLoader();
myListener = new Object();
myListener.onLoadComplete = function(targetMC)
{
targetMC.onPress = function ()
{
trace("pressed");
}
}
function initClips()
{
for (i=1;i<=4;i++)
{
this.attachMovie("img","img"+i,i);
this["img"+i]._x = i*110;
myMCL.loadClip(url,this["img"+i]);
}
}
myMCL.addListener(myListener);
initClips();
到此為止，你應(yīng)該相信MCL確實(shí)是一個不可多得的好東西了吧？
V2，也愛，也恨！這里介紹關(guān)于含有V2組件項(xiàng)目的loading問題
V2組件自面世以來就頗受爭議，大體概括如下：
優(yōu)點(diǎn)：
1、界面比V1組件更加美觀、統(tǒng)一，人機(jī)交互模式更加完善
2、均采用面向?qū)ο竽_本部署
缺點(diǎn)：
體積笨重，開發(fā)一些只用到一兩個組件的小應(yīng)用程序時很尷尬。
消息機(jī)制方面使用EventDispather的消息廣播機(jī)制，取代原有的AsBroadcast機(jī)制。使得剛出來的時候很多人根本不會用。
這里就不討論更多了，先說loading。含有大量v2組件的產(chǎn)品要想見人肯定是不能不作loading的，比如aw's blog左邊的那個blog小貼士。然而每次在loading的時候似乎都會遇到麻煩。那就是笨重的體積全部被放到第一幀導(dǎo)出了，這樣導(dǎo)致對一些300k以內(nèi)的，含有v2組件的SWF文件進(jìn)行遠(yuǎn)程載入的loading效果變得捉襟見肘。
解決的辦法也不是沒有，簡單概括為三個步驟：
一、去掉“Export in first frame”
二、在發(fā)布的時候設(shè)置一下“Export frame. for classes”,這一點(diǎn)非常重要!
三、對于外埠讀取的含有V2的swf文件，將容器mc進(jìn)行如下設(shè)置：
loader_mc._lockroot = true;
好了，現(xiàn)在放心享受精彩而笨重的V2組件吧~！